next | previous | forward | backward | up | top | index | toc | Macaulay2 web site
NormalToricVarieties :: isNef

isNef -- whether a torus-invariant Weil divisor is nef

Synopsis

Description

A -Cartier divisor is nef (short for "numerically effective" or "numerically eventually free") if the intersection product of the divisor with every complete irreducible curve is nonnegative. The definition depends only on the numerical equivalence class of the divisor. For a torus-invariant-Cartier divisor D on a complete normal toric variety, the following are equivalent:
  • D is nef;
  • some positive integer multiply of D is Cartier and basepoint free;
  • the real piecewise linear support function associated to D is convex.
A torus-invariant Cartier divisor is nef if and only if it is basepoint free; in other words, the associated line bundle is generated by its global sections.

On a Hirzebruch surface, three of the four torus-invariant prime divisors are nef.

i1 : X1 = hirzebruchSurface 2;
i2 : isNef X1_0

o2 = true
i3 : isAmple X1_0

o3 = false
i4 : isNef X1_1    

o4 = false
i5 : isNef X1_2

o5 = true
i6 : isAmple X1_2

o6 = false
i7 : isNef X1_3

o7 = true
i8 : isAmple X1_3

o8 = false
Not every -Cartier nef divisor is basepoint free.
i9 : X2 = weightedProjectiveSpace {2,3,5}

o9 = X2

o9 : NormalToricVariety
i10 : D = X2_1-X2_0

o10 = - D  + D
         0    1

o10 : ToricDivisor on X2
i11 : isNef D

o11 = true
i12 : HH^0(X2, OO D)

o12 = 0

o12 : QQ-module
i13 : for i from 1 to dim X2 list HH^i(X2, OO D)

o13 = {0, 0}

o13 : List
i14 : isCartier D    

o14 = false
i15 : isCartier (30*D)

o15 = true
i16 : HH^0(X2, OO (30*D))

        21
o16 = QQ

o16 : QQ-module, free
i17 : for i from 1 to dim X2 list HH^i(X2, OO (30*D))

o17 = {0, 0}

o17 : List
There are smooth complete normal toric varieties with no nontrivial nef divisors.
i18 : R2 = {{1,0,0},{0,1,0},{0,0,1},{0,-1,2},{0,0,-1},{-1,1,-1},{-1,0,-1},{-1,-1,0}};
i19 : S2 = {{0,1,2},{0,2,3},{0,3,4},{0,4,5},{0,1,5},{1,2,7},{2,3,7},{3,4,7},{4,5,6},{4,6,7},{5,6,7},{1,5,7}};  
i20 : X3 = normalToricVariety(R2,S2);    
i21 : isComplete X3

o21 = true
i22 : isProjective X3 

o22 = false
i23 : isSmooth X3

o23 = true
i24 : any(#rays X3, i -> isNef X3_i)

o24 = false
i25 : isNef (0*X3_1)    

o25 = true
The most basic vanishing theorem for normal toric varieties states that the higher cohomology of coherent sheaf associated to a nef divisor is zero.
i26 : X4 = kleinschmidt(9,{1,2,3});
i27 : isNef X4_0

o27 = true
i28 : isAmple X4_0

o28 = false
i29 : for i from 1 to dim X4 list HH^i(X4, OO X4_0)

o29 = {0, 0, 0, 0, 0, 0, 0, 0, 0}

o29 : List
i30 : D = X4_0+X4_4

o30 = D  + D
       0    4

o30 : ToricDivisor on X4
i31 : isNef D

o31 = true
i32 : isAmple D

o32 = true
i33 : for i from 1 to dim X4 list HH^i(X4, OO D)

o33 = {0, 0, 0, 0, 0, 0, 0, 0, 0}

o33 : List

See also

Ways to use isNef :