next | previous | forward | backward | up | top | index | toc | Macaulay2 web site
NormalToricVarieties :: weightedProjectiveSpace

weightedProjectiveSpace -- make a weighted projective space

Synopsis

Description

The weighted projective space associated to a list {q0,…, qd }, where no d-element subset of q0,…, qd has a nontrivial common factor, is a normal toric variety built from a fan in N = ℤd+1/ℤ(q0,…,qd). The rays are generated by the images of the standard basis for d+1 and the maximal cones in the fan correspond to the d-element subsets of {0,...,d}.

The first examples illustrate the defining data for three different weighted projective spaces.

i1 : PP4 = weightedProjectiveSpace {1,1,1,1};
i2 : rays PP4

o2 = {{-1, -1, -1}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}

o2 : List
i3 : max PP4

o3 = {{0, 1, 2}, {0, 1, 3}, {0, 2, 3}, {1, 2, 3}}

o3 : List
i4 : dim PP4

o4 = 3
i5 : X = weightedProjectiveSpace {1,2,3};
i6 : rays X

o6 = {{-2, -3}, {1, 0}, {0, 1}}

o6 : List
i7 : max X

o7 = {{0, 1}, {0, 2}, {1, 2}}

o7 : List
i8 : dim X

o8 = 2
i9 : ring X

o9 = QQ[x , x , x ]
         0   1   2

o9 : PolynomialRing
i10 : Y = weightedProjectiveSpace({1,2,2,3,4}, CoefficientRing => ZZ/32003, Variable => y);
i11 : rays Y

o11 = {{-2, -2, -3, -4}, {1, 0, 0, 0}, {0, 1, 0, 0}, {0, 0, 1, 0}, {0, 0, 0,
      -----------------------------------------------------------------------
      1}}

o11 : List
i12 : max Y

o12 = {{0, 1, 2, 3}, {0, 1, 2, 4}, {0, 1, 3, 4}, {0, 2, 3, 4}, {1, 2, 3, 4}}

o12 : List
i13 : dim Y

o13 = 4
i14 : ring Y

        ZZ
o14 = -----[y , y , y , y , y ]
      32003  0   1   2   3   4

o14 : PolynomialRing
The grading of the total coordinate ring for weighted projective space is determined by the weights. In particular, the class group is .
i15 : cl PP4

        1
o15 = ZZ

o15 : ZZ-module, free
i16 : degrees ring PP4

o16 = {{1}, {1}, {1}, {1}}

o16 : List
i17 : cl X

        1
o17 = ZZ

o17 : ZZ-module, free
i18 : degrees ring X

o18 = {{1}, {2}, {3}}

o18 : List
i19 : cl Y

        1
o19 = ZZ

o19 : ZZ-module, free
i20 : degrees ring Y

o20 = {{1}, {2}, {2}, {3}, {4}}

o20 : List
A weighted projective space is always simplicial but is typically not smooth
i21 : isSimplicial PP4

o21 = true
i22 : isSmooth PP4

o22 = true
i23 : isSimplicial X

o23 = true
i24 : isSmooth X

o24 = false
i25 : isSimplicial Y

o25 = true
i26 : isSmooth Y

o26 = false

See also

Ways to use weightedProjectiveSpace :